Как маркировать слово с помощью токенов, которые не полностью включены в слово?

Следующее, похоже, делает то, что вы хотите:

#!/usr/bin/env perl
use warnings;
use strict;

my @tokens = ('bEd', 'mA');
my $vowelizedword = "beEodamaA";

my @regex = map { join('.?', split //) . '.?' } @tokens;

my $regex = join('|', @regex);
$regex = qr/($regex)/;

while (my ($matched) = $vowelizedword =~ $regex) {
    $vowelizedword =~ s{$regex}{};
    print "matched $matched\n";
}

Обновите в соответствии с вашим обновленным вопросом (гласные не являются обязательными). Он работает с конца строки, поэтому вам придется собрать токены в массив и распечатать их в обратном порядке:

#!/usr/bin/env perl
use warnings;
use strict;

my @tokens = ('bEd', 'mA', 'Al', 'ywm');
my $vowelizedword = "beEodamaA Alyawmi"; # Caveat: Without the space it won't work.

my @regex = map { join('.?', split //) . '.?$' } @tokens;

my $regex = join('|', @regex);
$regex = qr/($regex)/;

while (my ($matched) = $vowelizedword =~ $regex) {
        $vowelizedword =~ s{$regex}{};
            print "matched $matched\n";
}

Используйте оператор m// в так называемом «контексте списка», например:

my @tokens = ($input =~ m/capturing_regex_here/modifiershere);

ETA: Насколько я понимаю сейчас, вы пытались сказать, что хотите сопоставить необязательную гласную после каждого символа токенов.

При этом вы можете настроить переменную $vowels так, чтобы она содержала только те буквы, которые вы ищете. При желании вы также можете просто использовать . для захвата любого персонажа.

use strict;
use warnings;
use Data::Dumper;

my @tokens = ("bEd", "mA");
my $full = "baEodamA";

my $vowels = "[aeiouy]";
my @matches;
for my $rx (@tokens) {
    $rx =~ s/.\K/$vowels?/g;
    if ($full =~ /$rx/) {
        push @matches, $full =~ /$rx/g;
    }
}

print Dumper \@matches;

Вывод:

$VAR1 = [
          'baEoda',
          'mA'
        ];

Обратите внимание, что

... $full =~ /$rx/g;

не требует захвата групп в регулярном выражении.

Я подозреваю, что есть более простой способ сделать то, что вы пытаетесь выполнить. Хитрость заключается не в том, чтобы сделать код генерации регулярных выражений настолько сложным, что вы забудете, что он на самом деле делает.

Я могу только догадываться о вашей задаче, но из вашего единственного примера похоже, что вы хотите проверить, что два подтокена находятся в большем токене, игнорируя определенные символы. Я собираюсь предположить, что эти суб-токены должны быть в порядке и между ними не может быть ничего, кроме этих гласных символов.

Чтобы сопоставить токены, я могу использовать привязку \G с глобальным флагом /g в скалярном контексте. Это привязывает совпадение к символу на единицу после окончания последнего совпадения для того же скаляра. Этот способ позволяет мне иметь отдельные шаблоны для каждого суб-токена. Это намного проще в управлении, так как мне нужно только изменить список значений в @subtokens.

Как только вы просмотрите каждую из пар и найдете, какие из них соответствуют всем шаблонам, я смогу извлечь исходную строку из пары.

use v5.14;

my $vowels    = '[ao]*';
my @subtokens = qw(bEd mA);

# prepare the subtoken regular expressions
my @patterns = map {
    my $s = join "$vowels", map quotemeta, (split( // ), '');
    qr/$s/;
    } @subtokens;

my @tokens = qw( baEodamA mAabaEod baEoda mAbaEoda );

my @grand_matches;
TOKEN: foreach my $token ( @tokens ) {
    say "-------\nMatching $token..........";
    my @matches;
    PATTERN: foreach my $pattern ( @patterns ) {
        say "Position is ", pos($token) // 0;

        # scalar context /g and \G
        next TOKEN unless $token =~ /\G($pattern)/g; 
        push @matches, $1;
        say "Matched with $pattern";
        }
    push @grand_matches, [ $token, \@matches ];
    }

# Now report the original   
foreach my $tuple ( @grand_matches ) {
    say "$tuple->[0] has both fragments: @{$tuple->[1]}";
    }

Теперь, вот хорошая вещь об этой структуре. Я, вероятно, неправильно угадал о вашей задаче. Если у меня есть, это легко исправить, не меняя настройки. Допустим, субтокены не обязательно должны быть в порядке. Это простое изменение шаблона, который я создал. Я просто избавился от якоря \G и флага /g;

        next TOKEN unless $token =~ /($pattern)/; 

Или предположим, что жетоны должны быть в порядке, но между ними могут быть другие вещи. Я могу вставить .*?, чтобы соответствовать этому материалу, эффективно пропуская его:

        next TOKEN unless $token =~ /\G.*?($pattern)/g; 

Было бы намного лучше, если бы я мог управлять всем этим из map, где я создаю шаблоны, но флаг /g не является флагом шаблона. Это должно быть связано с оператором.

Мне гораздо проще управлять изменяющимися требованиями, когда я не оборачиваю все в одно регулярное выражение.

Предполагая, что токены должны отображаться по порядку и без чего-либо (кроме гласной) между ними:

my @tokens = ( "bEd", "mA" );
my $vowelizedword = "baEodamaA";

my $vowels = '[ao]';
my (@vowelized_sequences) = $vowelizedword =~ ( '^' . join( '', map "(" . join( $vowels, split( //, $_ ) ) . "(?:$vowels)?)", @tokens ) . '\\z' );
print for @vowelized_sequences;