Определить и заменить выборочное пространство внутри данного текстового файла

Следующий сценарий sed с комментариями с вводом из bash здесь строка:

<<<'my data "this is my very first encounter with sed"  "valuable" - - "c l e a r"' sed -E '
    # Split input with each character on its own line
    s/./&\n/g;
    # Add a newline on the end to separate output from input
    s/$/\n/;
    # Each line has one character
    # Add a leading character that stores "state"
    # There are two states available - in quoting or not in quoting
    # The state character is space when we are not in quotes
    # The state character is double quote when we are in quotes
    s/^/ /;
    # For each character in input
    :again; {
        # Substitute a space that is not in quotes for a comma
        s/^  / ,/

        # When quotes is encountered and we are not in quotes
        /^ "/{
            # Change state to quotes
            s//""/
            b removed_quotes
        } ; {
            # When quotes is encountered and we are in quotes
            # then we are no longer in quotes
            s/^""/ "/
        } ; : removed_quotes

        # Preserve state as the first character
        # Add the parsed character to the output on the end
        # Preserve the rest
        s/^(.)(.)\n(.*)/\1\3\2/;
        # If end of input was not reached, then parse another character.
        /^.\n/!b again;
    };
    # Remove the leading state character with the newline
    s///;
'

выходы:

my,data,"this is my very first encounter with sed",,"valuable",-,-,"c l e a r"

И один лайнер, потому что кто читает эти комментарии:

sed -E 's/./&\n/g;s/$/\n/;s/^/ /;:a;s/^  / ,/;/^ "/{s//""/;bq;};s/^""/ "/;:q;s/^(.)(.)\n(.*)/\1\3\2/;/^.\n/!ba;s///'

Я думаю, что новая строка \n в строке замены команды s - это расширение, которое не требуется posix. Другой уникальный символ может использоваться вместо новой строки для разделения ввода во время синтаксического анализа. Во всяком случае, я тестировал это с помощью GNU sed.

Как упоминалось в комментариях, это лучше подходит для реального парсера CSV, вместо того, чтобы пытаться что-то накапливать, используя регулярные выражения - особенно довольно простые регулярные выражения sed.

Однострочный perl с использованием полезного модуля Text :: AutoCSV (устанавливается через вашу ОС менеджер пакетов или любимый клиент CPAN):

$ perl -MText::AutoCSV -e 'Text::AutoCSV->new(sep_char=>" ", out_sep_char=>",")->write' < input.txt
my,data,"this is my very first encounter with sed",,valuable,-,-,"c l e a r"

С GNU awk для FPAT:

$ awk -v FPAT='[^ ]*|"[^"]+"' -v OFS=',' '{$1=$1} 1' file
my,data,"this is my very first encounter with sed",,"valuable",-,-,"c l e a r"

Ваш ввод - это CSV, где C в этом случае означает символ вместо традиционной запятой, а рассматриваемый символ является пустым, и вы просто пытаетесь преобразовать его в CSV с разделителями-запятыми. См. Какой самый надежный способ эффективного синтаксического анализа CSV с помощью awk? для получения дополнительной информации о том, что делает вышеперечисленное, и о синтаксическом анализе CSV с awk в целом.

awk 'BEGIN {RS=ORS="\""} NR%2 {gsub(" ",",")} {print}' file

• Вначале установите двойные кавычки в качестве разделителя записей.
• Для нечетных записей, то есть вне кавычек, замените глобально любой пробел запятой.
• распечатать каждую запись.

Это может сработать для вас (GNU sed):

sed -E ':a;s/^((("[^"]*")*[^" ]*)*) /\1,/;ta' file

Заменить, группу из нуля или более строк в двойных кавычках, за которыми следуют ноль или более непробельных символов, ноль или более раз, за ​​которыми следует пробел с группой, за которой следует запятая, повторяется до отказа.